Databasefuncties

Overzicht

De twaalf functies in de categorie Database helpen u bij het analyseren van een eenvoudige database die een rechthoekig werkbladgebied beslaat met kolommen en rijen, waarbij de gegevens als één rij voor elk record zijn georganiseerd. De koptekstcel van elke kolom geeft de naam van de kolom weer en die naam geeft meestal de inhoud van elke cel in die kolom weer.

De functies in de categorie Database hebben de volgende drie argumenten:

  1. Database. Het celbereik van de database.

  2. DatabaseVeld. De kolom die de gegevens bevat, die in de berekening van de functie gebruikt wordt.

  3. ZoekCriteria. Het celbereik van een afzonderlijk gebied van het werkblad met zoekcriteria..

Deze argumenten worden hieronder uitgebreider beschreven.

Alle functies hebben hetzelfde algemene bedieningsconcept. De eerste logische stap is om de gespecificeerde ZoekCriteria te gebruiken om de subset van records in de Database te identificeren die tijdens volgende berekeningen moeten worden gebruikt. De tweede stap is het extraheren van de gegevenswaarden en het uitvoeren van de berekeningen die zijn gekoppeld aan de specifieke functie (gemiddelde, som, product, enzovoort). De verwerkte waarden zijn die in de kolom DatabaseVeld van de geselecteerde records.

note

Calc behandelt datums en logische waarden (WAAR en ONWAAR) als numeriek bij het berekenen met deze functies.


Databasefunctie-argumenten

De volgende argumentdefinities zijn van toepassing op alle functies in de categorie Database:

  1. Database-argumenten

    Database specificeert het celbereik dat wordt ingenomen door de databasetabel. De eerste rij van het bereik bevat de veldnamen en de volgende rijen zijn records met bijbehorende veldwaarden.

    Een manier om het celbereik te definiëren, is door de celverwijzing voor de cel linksboven in te voeren, gevolgd door een dubbele punt (:), en vervolgens de celverwijzing rechtsonder. Een voorbeeld kan A1:E10 zijn.

    Het argument Database kan ook worden gespecificeerd door de naam van een benoemd bereik of databasebereik door te geven. Het gebruik van een betekenisvolle naam om het celbereik te definiëren, kan de leesbaarheid van de formule en het documentonderhoud verbeteren. Als de naam niet overeenkomt met de naam van een gedefinieerd bereik, rapporteert Calc een #NAAM? fout.

    Andere fouten die kunnen worden gemeld als gevolg van een ongeldig Database-argument zijn #WAARDE! en FOUT:504 (fout in parameterlijst).

  2. DatabaseVeld-argument

    DatabaseVeld specificeert de kolom die de functie zal gebruiken voor zijn berekeningen nadat de zoekcriteria zijn toegepast en de gegevensrijen zijn geselecteerd. Het is niet gerelateerd aan de zoekcriteria.

    Geef het argument DatabaseVeld op een van de volgende manieren op:

    • Door een verwijzing naar een kopcel in het gebied Database in te voeren. Als alternatief, als de cel een betekenisvolle naam heeft gekregen als een benoemd bereik of databasebereik, voert u die naam in. Als de naam niet overeenkomt met de naam van een gedefinieerd bereik, rapporteert Calc een #NAAM? fout. Als de naam geldig is maar niet overeenkomt met slechts één cel, rapporteert Calc FOUT:504 (fout in parameterlijst).

    • By entering a number to specify the column within the Database area, starting with 1. For example, if a Database occupied the cell range D6:H123, then enter 3 to indicate the header cell at F6. Calc expects an integer value that lies between 1 and the number of columns defined within Database and ignores any digits after a decimal point. If the value is less than 1, Calc reports Err:504 (error in parameter list). If the value is greater than the number of columns in Database, Calc reports a #VALUE! error.

    • By entering the literal column header name from the first row of the Database range, placing quotation marks around the header name. For example, “Distance to School”. If the string does not match one of the Database area’s column headings, Calc reports Err:504 (error in parameter list). You can also provide a reference to an arbitrary cell (not within the Database and SearchCriteria areas) that contains the required string.

    The DatabaseField argument is optional for the DCOUNT and DCOUNTA functions but it is required for the other ten Database functions.

  3. SearchCriteria argument

    SearchCriteria specifies the range of cells containing search criteria. Like Database, its first row is also field names, and subsequent rows are conditions for related fields. The Database and SearchCriteria areas need not be adjacent, or even on the same sheet.

    Een manier om het celbereik te definiëren, is door de celverwijzing voor de cel linksboven in te voeren, gevolgd door een dubbele punt (:), en vervolgens de celverwijzing rechtsonder. Bijvoorbeeld A13:B14. Het celbereik kan ook worden gespecificeerd door de naam van een gedefinieerd benoemd bereik of databasebereik door te geven. Als de naam niet overeenkomt met de naam van een gedefinieerd bereik, rapporteert Calc een #NAAM? fout.

    Err:504 (fout in parameterlijst) kan ook worden gerapporteerd als gevolg van een ongeldig ZoekCriteria-argument.

    De inhoud van het gebied ZoekCriteria wordt in de volgende sectie in meer detail beschreven.

ZoekCriteria definiëren

Het aantal kolommen dat wordt ingenomen door het gebied ZoekCriteria hoeft niet hetzelfde te zijn als de breedte van het gebied Database. Alle koppen die in de eerste rij van ZoekCriteria verschijnen, moeten identiek zijn aan koppen in de eerste rij van Database. Niet alle koppen in Database hoeven echter in de eerste rij van ZoekCriteria te verschijnen, terwijl een kop in Database meerdere keren in de eerste rij kan voorkomen van ZoekCriteria.

Zoekcriteria worden ingevoerd in de cellen van de tweede en volgende rijen van het gebied ZoekCriteria, onder de rij met koppen. Lege cellen in het gebied ZoekCriteria worden genegeerd.

Maak criteria in de cellen van het gebied ZoekCriteria met behulp van de vergelijkingsoperatoren <, <=, =, <>, >= en >. = wordt aangenomen als een cel niet leeg is maar niet begint met een vergelijkingsoperator.

Als u meerdere criteria in één rij schrijft, zijn ze verbonden door EN. Als u meerdere criteria in verschillende rijen schrijft, zijn ze verbonden door OF.

Criteria kunnen worden gemaakt met jokertekens, op voorwaarde dat jokertekens zijn ingeschakeld via de optie Jokertekens inschakelen in formules op de - LibreOffice Calc - Bereken dialoogvenster. Als interoperabiliteit met Microsoft Excel belangrijk is voor uw werkblad, moet deze optie worden ingeschakeld.

Met reguliere expressies kunnen nog krachtigere criteria worden gemaakt, op voorwaarde dat reguliere expressies zijn ingeschakeld via de optie Reguliere expressies in formules toestaan in het dialoogvenster - LibreOffice Calc - Berekenen.

warning

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".


Een andere instelling die van invloed is op hoe de zoekcriteria worden behandeld, is de optie Zoekcriteria = en <> moeten van toepassing zijn op hele cellen in het dialoogvenster - LibreOffice Calc - Berekenen . Deze optie bepaalt of de zoekcriteria die u instelt voor de databasefuncties exact moeten overeenkomen met de hele cel. Als interoperabiliteit met Microsoft Excel belangrijk is voor uw werkblad, moet deze optie worden ingeschakeld.

Voorbeelden van gebruik van databasefuncties

De volgende tabel bevat een voorbeelddatabasetabel die wordt gebruikt om te demonstreren hoe u de functies in de categorie Database kunt gebruiken. Het celbereik A1:E10 bevat fictieve informatie over de gasten die zijn uitgenodigd voor Joe's verjaardagsfeestje. De volgende informatie wordt voor elke gast gegeven: naam, klas, leeftijd in jaren, afstand tot school in meters en gewicht in kilogram.

A

B

C

D

E

1

Naam

Cijfer

Leeftijd

Afstand

Gewicht

2

Andy

3

9

150

40

3

Bettie

4

10

1000

42

4

Karel

3

10

300

51

5

Danny

5

11

1200

48

6

Eva

2

8

650

33

7

Frank

2

7

300

42

8

Grietje

1

7

200

36

9

Harrie

3

9

1200

44

10

Irene

2

8

1000

42

11


De volgende zes voorbeelden gebruiken de bovenstaande databasetabel, gecombineerd met verschillende zoekcriteriagebieden.

Voorbeeld 1

A

B

C

D

E

12

Naam

Cijfer

Leeftijd

Afstand

Gewicht

13

>600

14


Zoals in dit eenvoudige voorbeeld is het soms wenselijk (maar niet essentieel) om het zoekcriteriagebied direct onder de databasetabel te plaatsen, met de kolommen van de twee gebieden verticaal uitgelijnd. Lege vermeldingen in het gebied met zoekcriteria worden genegeerd. Voeg met de bovenstaande voorbeelddatabasetabel en dit zoekcriteriagebied de formule =DCOUNT(A1:E10;;A12:E14) in een lege cel elders in het blad in om te tellen hoe veel van Joe's gasten reizen verder dan 600 meter naar school. De waarde 5 wordt geretourneerd (Bettie, Danny, Eva, Harrie en Irene meegerekend).

Merk ook op dat de formule =DCOUNT(A1:E10;;D12:D13) exact dezelfde waarde retourneert, wat aantoont dat het alleen nodig is dat het zoekcriteriagebied de relevante kolom bevat rubrieken.

Voorbeeld 2

   A   

   B   

   C   

   D   

   E   

12

Leeftijd

Cijfer

13

>7

2

14


In dit voorbeeld bevat het zoekcriteriagebied slechts twee koppen en deze zijn niet verticaal uitgelijnd met de corresponderende koppen in de voorbeelddatabasetabel. Omdat er twee voorwaarden in dezelfde rij staan, zijn deze verbonden door EN. Voeg met de bovenstaande voorbeelddatabasetabel en dit zoekcriteriagebied de formule =DCOUNT(A1:E10;;B12:C13) in een lege cel elders in het blad in om te tellen hoe veel van Joe's gasten zitten in groep 2 en zijn ouder dan 7 jaar. De waarde 2 wordt geretourneerd (Eva en Irene meegerekend).

Voorbeeld 3

   A   

   B   

   C   

   D   

   E   

12

Leeftijd

13

9

14

10


In dit voorbeeld bevat het gebied met zoekcriteria slechts één kop. Aangezien er twee voorwaarden in opeenvolgende rijen zijn, zijn deze verbonden door OR. Voeg met de bovenstaande voorbeelddatabasetabel en dit zoekcriteriagebied de formule =DCOUNT(A1:E10;;B12:B14) in een lege cel elders in het blad in om te tellen hoe veel van Joe's gasten zijn 9 of 10 jaar oud. De waarde 4 wordt geretourneerd (Andy, Bettie, Karel en Harrie meegerekend).

Voorbeeld 4

   A   

   B   

   C   

   D   

   E   

12

Leeftijd

Leeftijd

13

>=8

<=10

14


In dit voorbeeld bevat het gebied met zoekcriteria twee exemplaren van dezelfde kop. Omdat er twee voorwaarden in dezelfde rij staan, zijn deze verbonden door AND. Voeg met de bovenstaande voorbeelddatabasetabel en dit zoekcriteriagebied de formule =DCOUNT(A1:E10;;B12:C13) in een lege cel elders in het blad in om te tellen hoe veel van Joe's gasten zijn tussen de 8 en 10 jaar (inclusief). De waarde 6 wordt geretourneerd (Andy, Bettie, Karel, Eva, Harrie en Irene meegerekend).

Voorbeeld 5

   A   

   B   

   C   

   D   

   E   

12

Naam

13

F*

14


Dit eenvoudige voorbeeld toont het gebruik van jokertekens. Om dit voorbeeld te laten werken zoals bedoeld, selecteert u om jokertekens in te schakelen op - LibreOffice Calc - Berekenen. Voeg met de bovenstaande voorbeelddatabasetabel en dit zoekcriteriagebied de formule =DCOUNT(A1:E10;;A12:A13) in een lege cel elders in het blad in om te tellen hoe veel van Joe's gasten hebben namen die beginnen met de letter "F". De waarde 1 wordt geretourneerd (Frank meegerekend).

Voorbeeld 6

   A   

   B   

   C   

   D   

   E   

12

Naam

13

[ABC].*

14


This simple example shows the use of regular expressions. For this example to work as intended, select to enable regular expressions at - LibreOffice Calc - Calculate. With the above example database table and this search criteria area, insert the formula =DCOUNT(A1:E10;;A12:A13) into an empty cell elsewhere in the sheet to count how many of Joe’s guests have names that begin with the letters “A”, “B”, or “C”. The value 3 is returned (counting Andy, Betty, and Charles).

DBAANTAL

DCOUNT counts the number of cells (fields) of the specified column that contain numeric values, for all rows (database records) that match the specified search criteria. However, if no column is specified, DCOUNT returns the count of all records that match the specified search criteria irrespective of their contents.

Syntaxis

DBAANTAL(Database; [Databaseveld]; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">600" (this search criterion will match records in the database table that have a value greater than 600 in the Distance column).

Insert the formula =DCOUNT(A1:E10;; A12:E13) into an empty cell elsewhere in the sheet to calculate how many of Joe’s party guests travel further than 600 meters to school. The value 5 is returned.

The same result is obtained if you use the formula =DCOUNT(A1:E10; "Distance"; A12:E13), because all entries in the Distance column are numeric. However, if you use the formula =DCOUNT(A1:E10; "Name"; A12:E13), the value 0 is returned because all entries in the Name column are non-numeric.

DBAANTALC

DCOUNTA counts the number of cells (fields) of the specified column that are not blank, for all rows (database records) that match the specified search criteria. Blank cells of the specified column are not counted. However, if no column is specified, DCOUNTA returns the count of all records that match the specified search criteria irrespective of their contents.

Syntaxis

DBAANTALC(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">600" (this search criterion will match records in the database table that have a value greater than 600 in the Distance column).

Insert the formula =DCOUNTA(A1:E10;; A12:E13) into an empty cell elsewhere in the sheet to calculate how many of Joe’s party guests travel further than 600 meters to school. The value 5 is returned.

The same result is obtained if you use the formula =DCOUNTA(A1:E10; "Distance"; A12:E13) or the formula =DCOUNTA(A1:E10; "Name"; A12:E13). The latter case reflects that in contrast to DCOUNT, DCOUNTA counts both numeric and alphanumeric values in the column indicated by the DatabaseField argument.

DBGEMIDDELDE

DAVERAGE calculates the average of the numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Non-numeric values in those cells are ignored.

Returns a #DIV/0! error if no records match the specified search criteria, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBGEMIDDELDE(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DAVERAGE(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to calculate the average distance in meters travelled to school by Joe’s party guests. The value 666.67 is returned.

DBLEZEN

DGET returns the contents of the cell (field) of the specified column, for the single row (database record) that matches the specified search criteria.

Calc reports Err:502 (invalid argument) if multiple matches are found, or a #VALUE! error (wrong data type) if no matches are found. A #VALUE! error is also reported if a single match is found but the relevant cell is empty.

Syntaxis

DBLEZEN(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell C13 which should contain "11" (this search criterion will match records in the database table that have a value of 11 in the Age column).

Insert the formula =DGET(A1:E10; "Name"; A12:E13) into an empty cell elsewhere in the sheet to find the name of Joe’s party guest who is age 11. The name Daniel is returned.

If you change the value in cell C13 to “10”, then the formula =DGET(A1:E10; "Name"; A12:E13) returns an invalid argument error (Err:502). The reflects that multiple records match the specified criterion (both Betty and Charles are age 10).

DBMAX

DMAX calculates the maximum value across the cells (fields) of the specified column that contain numeric values, for all rows (database records) that match the specified search criteria. Blank cells or cells containing non-numeric characters are not included.

Returns 0 if no matches are found, or if there are no non-zero numeric values in the cells of the specified column for the matching records.

Syntaxis

DBMAX(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DMAX(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to find the maximum distance in meters that any of Joe’s party guests travel to school. The value 1200 is returned.

DBMIN

DMIN calculates the minimum value across the cells (fields) of the specified column that contain numeric values, for all rows (database records) that match the specified search criteria. Blank cells or cells containing non-numeric characters are not included.

Returns 0 if no matches are found, or if there are no non-zero numeric values in the cells of the specified column for the matching records.

Syntaxis

DBMIN(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DMIN(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to find the minimum distance in meters that any of Joe’s party guests travel to school. The value 150 is returned.

DBPRODUCT

DPRODUCT calculates the product of all numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Blank cells or cells containing non-numeric characters are not included.

Returns 0 if no matches are found, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBPRODUCT(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell C13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DPRODUCT(A1:E10; "Age"; A12:E13) into an empty cell elsewhere in the sheet to calculate the product of the ages in years of Joe’s party guests. The value 279417600 is returned.

DBSOM

DSUM calculates the sum of all numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Blank cells or cells containing non-numeric characters are not included.

Returns 0 if no matches are found, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBSOM(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DSUM(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to find the total distance in meters that all of Joe’s party guests travel to school. The value 6000 is returned.

DBSTDEV

DSTDEV calculates the sample standard deviation based on the numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Non-numeric values are ignored.

Returns a #NUM! error if exactly one record matches the specified search criteria, or if there is only one numeric value in the cells of the specified column for the matching records.

Returns 0 if no matches are found, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBSTDEV(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:D13 are blank and that cell E13 contains ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DSTDEV(A1:E10; "Weight"; A12:E13) into an empty cell elsewhere in the sheet to calculate the sample standard deviation of the weights in kg of Joe’s party guests. The value 5.5 is returned.

DBSTDEVP

DSTDEVP calculates the population standard deviation based on the numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Non-numeric values are ignored.

Returns a #NUM! error if no records match the specified search criteria, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBSTDEVP(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:D13 are blank and that cell E13 contains ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DSTDEVP(A1:E10; "Weight"; A12:E13) into an empty cell elsewhere in the sheet to calculate the population standard deviation of the weights in kg of Joe’s party guests. The value 5.18545 is returned.

DBVAR

DVAR calculates the sample variance based on the numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Non-numeric values are ignored.

Returns a #NUM! error if exactly one record matches the specified search criteria, or if there is only one numeric value in the cells of the specified column for the matching records.

Returns 0 if no matches are found, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBVAR(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DVAR(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to find the sample variance of the distances in meters that Joe’s party guests travel to school. The value 193125 is returned.

DBVARP

DVARP calculates the population variation based on the numeric values in the cells (fields) of the specified column, for all rows (database records) that match the specified search criteria. Non-numeric values are ignored.

Returns a #NUM! error if no records match the specified search criteria, or if there are no numeric values in the cells of the specified column for the matching records.

Syntaxis

DBVARP(Database; Databaseveld; Zoekcriteria)

Voorbeeld

The example database table giving information about the guests invited to Joe’s birthday party (described above) should occupy cells A1:E10. The content of cells A12:E12 should be identical to the header labels for the database table in cells A1:E1. Make sure that cells A13:E13 are blank, except for cell D13 which should contain ">0" (this search criterion is intended to match all records in the database table).

Insert the formula =DVARP(A1:E10; "Distance"; A12:E13) into an empty cell elsewhere in the sheet to find the population variance of the distances in meters that Joe’s party guests travel to school. The value 171666.67 is returned.